Need a book? Engineering books recommendations...

Return to index: [Subject] [Thread] [Date] [Author]

ANSYS Transient Analysis ... Reply

[Subject Prev][Subject Next][Thread Prev][Thread Next]
Hi  Haris,

Hereafter is an example for transient analysis with ANSYS 5.4/5.5



! First you define the geometry
! This block ends with the following two commands:
SAVE
FINI
!
/SOLU
ANTYP,TRANS                      !  Transient Dynamic Analysis
NLGEOM,ON
CNVTOL,F,,0.01,2,10.0
CNVTOL,U,,0.001,2
PRED,ON
NCNV,0
!
*DIM,A1,TABLE,2048,1             ! Define Data Arrays for the
*DIM,A2,TABLE,2048,1             ! accelerograms
*DIM,A3,TABLE,2048,1
!
*VREAD,A1(1,1),zvl_x13,acc       ! Read Acceleration in X
(E13.5)
*VFILL,A1(1,0),RAMP,0.0,0.010
A1(0,1)=1.0
*VPLOT,A1(1,0),A1(1,1)
!
*VREAD,A2(1,1),zvl_y13,acc       ! Read Acceleration in Y
(E13.5)
*VFILL,A2(1,0),RAMP,0.0,0.010
A2(0,1)=1.0
*VPLOT,A2(1,0),A2(1,1)
!
*VREAD,A3(1,1),zvl_z13,acc       ! Read Acceleration in Z
(E13.5)
*VFILL,A3(1,0),RAMP,0.0,0.010
A3(0,1)=1.0
*VPLOT,A3(1,0),A3(1,1)
!
D,800,ALL,0.0                    ! Define Constarains
D,900,ALL,0.0
D,806,UX,0.0
D,806,UZ,0.0
D,920,UX,0.0
!
TIME,1.0E-5
DT=0.0050
T0=0.01
T1=14.99
!                 ! Rayleigh Damping
ALPHAD,1.2566     ! alpha and beta so, that
BETAD,7.07355E-4  ! D=0.07 for f=1.5Hz and f=30Hz
OUTRES,ALL,NONE
!
TIMINT,OFF        ! Initial Conditions for Dead Weight
DELTIM,0.5E-5
KBC,1
ACEL,0.0,0.0,9.81
SOLVE
!
TIMINT,ON         ! Conditions for Dynamic Analysis
KBC,0
DELTIM,0.0050
AUTOTS,ON
NSUBST,1,10,1,OFF
*DO,T,T0,T1,DT
    OUTRES,NSOL,LAST
    OUTRES,MISC,LAST,ROST
    OUTRES,MISC,LAST,PLAT
    OUTRES,MISC,LAST,FEDE
   TIME,T
   AX=A1(T)
   AY=A2(T)
   AZ=A3(T)+9.81
   ACEL,AX,AY,AZ
   SOLVE
*ENDDO
!
!
/POST26               ! Postproccessing
NUMVAR,199
/RESET
!
! ----- Schnittkraefte im linken Unterzug -----
!
M=262                 ! Anfangsnummer
N=277                 ! Endnummer
L=2                     ! ESOL-Variablennummer
*DO,I,M,N,1
 ESOL,L+0,I,,SMISC,1,UzL.%I%
 ESOL,L+1,I,,SMISC,2,UzL.%I%
 ESOL,L+2,I,,SMISC,3,UzL.%I%
 ESOL,L+3,I,,SMISC,4,UzL.%I%

etc, etc .............................................



!
! ----- Verschiebung des Behaelterkopfmittelpunktes -----
!
NSOL,3,5,U,X
NSOL,4,5,U,Y
NSOL,5,5,U,Z
!
!
! ----- 7. Plot -----
!
/AXLAB,X,Zeit [s]
/AXLAB,Y,Z-Verschiebung Behaelterkopf [m]
PLVAR,5
!
! ----- 8. Plot -----
!
XVAR,3
/XRANGE,DEFAULT
/AXLAB,X,X-Verschiebung Behaelterkopf [m]
/AXLAB,Y,Y-Verschiebung Behaelterkopf [m]
PLVAR,4
!
!
FINI
/EXIT             ! Do not forget this command at the end                



Best regards,
Peter

===========================
Dr. Peter Rangelow
HOCHTIEF, Abt. IKS
Bockenheimer Landstrasse 24
60323 Frankfurt, GERMANY
Phone:	+(49-69) 7117-2539
Fax:	+(49-69) 7117-2782
Email:	Peter.Rangelow(--nospam--at)hochtief.de
===========================